***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 25, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P2AL8P0A A K 
.param
+vc0 = 2.106e-11		vc1 = 3.056e-11		vc2 = 1.400			vc3 = 1.065e-14		vc4 = 1.549e+0
+tc1 = 4.081e-2		tc2 = 2.411e-2		tc3 = 6.701e-3		tc4 = 6.021e-3
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.329e-14	 	   n = 1.035		  rs = 2.232e-2
+ibv = 1.0e-3		 nbv = 1.0			  bv = 9.36
+ikf = 3.073e+1
***** capacitance parameter *****
+cjo = 8.787e-10		   m = 3.327e-1		  vj = 6.294e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25			  eg = 1.130		 xti = 3
+trs1 = -1e-4		trs2 = -1e-6		tikf = 1.0e-2
+tbv1 = 5.935e-4		tbv2 = -2.194e-8	
.ends P2AL8P0A
*$
